Adott dátumon felvett termékek
Melyik azok a termékek amelyek a paraméterben megadott dátumon kerültek felvételre
SELECT
T.Kod, T.Nev, T.Megjegyzes
FROM
Termek T
WHERE
T.FelvDatum >= @Datum AND T.FelvDatum < @Datum + 1
ORDER BY
T.Kod
helyett a következőt kell létrehozni:
ALTER PROCEDURE [dbo].[C1_TermekL]
@Leiro Logikai = NULL,
--Forditas
@FeliratNyelv_ID SorszamKoz = NULL,
@AdatNyelv_ID SorszamKoz = NULL,
--Szures
@Datum Datum = NULL
AS
SET NOCOUNT ON
SET XACT_ABORT ON
SET ANSI_PADDING ON
SET ANSI_WARNINGS ON
SET ARITHABORT ON
SET CONCAT_NULL_YIELDS_NULL ON
SET NUMERIC_ROUNDABORT OFF
IF @Leiro = 1
BEGIN
SELECT
ListID='AltalanosXLS',
(SELECT
Type='Forditas',
(SELECT Caption='Felirat nyelv', ParameterName='FeliratNyelv_ID', SCBType='Nyelv', DefaultValue=FeliratNyelv_ID FOR XML RAW('Control'), TYPE),
(SELECT Caption='Adat nyelv', ParameterName='AdatNyelv_ID', SCBType='Nyelv', DefaultValue=AdatNyelv_ID FOR XML RAW('Control'), TYPE)
FROM
Felhasznalo
WHERE
Felhasznalo_ID = dbo.Felhasznalo_ID()
FOR XML RAW('Band'), TYPE),
(SELECT
Type='Szures',
(SELECT Caption='Dátum', ParameterName='Datum', DataType='DATE', Nullable=0 FOR XML RAW('Control'), TYPE)
FOR XML RAW('Band'), TYPE),
(SELECT
'EXEC dbo.C1_TermekL
@FeliratNyelv_ID=:FeliratNyelv_ID,
@AdatNyelv_ID=:AdatNyelv_ID,
@Datum=:Datum' AS [text()]
FOR XML PATH('SP'), TYPE)
FOR XML RAW('Form'), TYPE
RETURN
END;
DECLARE @XMLDoc XML
SET @XMLDoc = (
SELECT
(SELECT
(SELECT KodAlpha2 FROM Nyelv WHERE Nyelv_ID = @FeliratNyelv_ID) AS lang,
(SELECT CegNev FROM SajatAdat WHERE Nev = 'Normál') AS CegNev,
(SELECT Nev FROM Felhasznalo WHERE Felhasznalo_ID = dbo.Felhasznalo_ID()) AS Felhasznalo,
CONVERT(VARCHAR, GETDATE(), 102) + '. ' + CONVERT(VARCHAR, GETDATE(), 108) AS Idopont
FOR XML RAW('Fejlec'), ROOT('Parameterek'), TYPE),
(SELECT
dbo.SzotarSzoveg('Termék lap', @FeliratNyelv_ID) AS Nev,
dbo.SzotarSzoveg('A megadott dátumon felvett termékek', @FeliratNyelv_ID) AS Cim,
3 AS UtolsoOszlop,
'n0' AS T,
(SELECT
dbo.SzotarSzoveg('A megadott dátumon felvett termékek', @FeliratNyelv_ID) AS ListaNev,
(SELECT
(SELECT 1 AS [@O], dbo.SzotarSzoveg('Termék kód', @FeliratNyelv_ID) AS [text()] FOR XML PATH('C'), TYPE),
(SELECT 2 AS [@O], 48 AS [@W], dbo.SzotarSzoveg('Termék név', @FeliratNyelv_ID) AS [text()] FOR XML PATH('C'), TYPE),
(SELECT 3 AS [@O], dbo.SzotarSzoveg('Megjegyzés', @FeliratNyelv_ID) AS [text()] FOR XML PATH('C'), TYPE)
FOR XML RAW('Sor'), TYPE)
FOR XML RAW('Fejlec'), TYPE),
(SELECT
(SELECT 1 AS [@O], 'Txt' AS [@T], T.Kod AS [text()] FOR XML PATH('C'), TYPE),
(SELECT 2 AS [@O], 'Txt' AS [@T], T.Nev AS [text()] FOR XML PATH('C'), TYPE),
(SELECT 3 AS [@O], 'Txt' AS [@T], T.Megjegyzes AS [text()] FOR XML PATH('C'), TYPE)
FROM
Termek T
WHERE
T.FelvDatum >= @Datum
AND T.FelvDatum < @Datum + 1
ORDER BY
T.Kod
FOR XML RAW('Sor'), TYPE)
FOR XML RAW('Lap'), TYPE)
FOR XML PATH('AltalanosXLS'), TYPE)
IF OBJECT_ID('tempdb.dbo.#AdatforrasEredmeny') IS NULL
SELECT @XMLDoc
ELSE
INSERT INTO #AdatforrasEredmeny VALUES (@XMLDoc)
